Post History

# [Brain-Flak], 250 bytes

    ((((()()()){}){}){}()){(({})[()])}{}(<>)<>{({}<>)<>}<>{(({})[()])}([]){{}([(({}))](((()()()){}){}){}()){({}[()])<>((((()()()()){}){}){})<>}{}<>(((((()()()()){}){}){}){}())<>{({}[()])<>(({})())<>}{}{({}[()])<>(({})[()])<>}{}<>((()()()()()){})<>([])}<>

[Try it online!][TIO-kl1xxz7l]

[Brain-Flak]: https://github.com/DJMcMayhem/Brain-Flak
[TIO-kl1xxz7l]: https://tio.run/##dY4xDoAgDEWv0w7cgJB4DsKgg4nROLgSzl5/iwoxCgw/r@2j0zEuu5u3cRUhPayXc6lPIxFiJE5cAHxgHzKQhaK51SkmzmiKxjj9CHOxdh/aj12LalVP31Vz1BUeC7BBzL35lW8j90IQLIyCiLhjOAE "Brain-Flak – Try It Online"

Readable, commented version:

    # Push 25
    ((((()()()){}){}){}())
    
    # Push range(25, 1)
    {
        (({})[()])
    }
    {}
    
    # Push a 0 on to the alternate stack and return to main stack
    (<>)<>
    
    # Reverse values onto other stack
    {
        ({}<>)
        <>
    }
    <>
    
    # Push range(25, 0)
    {
        (({})[()])
    }
    
    # Push the stack height.
    ([])
    
    # At this point, the stack has 0, 1, 2... 23, 24, 25, 24, 23... 2, 1, 0
    # Go through each number of these numbers, and call it N
    {
        # Pop the stack height counter
        {}
    
        # Push (25 - N), and underneath it push N an additional time
        ([(({}))](((()()()){}){}){}())
    
        # That many times...
        {
            # Decrement
            ({}[()])
    
            <>
    
            # Push a space onto the ascii-art stack
            ((((()()()()){}){}){})
    
            <>
        }
        {}
    
        # on the ascii-art stack, push the letter A
        <>
        (((((()()()()){}){}){}){}())
        <>
    
        # N times...
        {
            # Decrement N
            ({}[()])
    
            # Push "The last character + 1"
            <>
            (({})())
            <>
        }
        {}
    
        # N times...
        {
            # Decrement N
            ({}[()])
    
            # Push "The last character - 1"
            <>
            (({})[()])
            <>
        }
        {}
    
        <>
        # Push a newline
        ((()()()()()){})
        <>
    
        ([])
    }<>